From 1227bee3d2916a208a995430db2e5e0288354f43 Mon Sep 17 00:00:00 2001
From: Simeon Simeonov
Date: Mon, 4 May 2020 09:57:42 +0200
Subject: Add x11-terms/terminator

---
 x11-terms/terminator/terminator-1.92.ebuild | 59 +++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 x11-terms/terminator/terminator-1.92.ebuild

(limited to 'x11-terms/terminator/terminator-1.92.ebuild')

diff --git a/x11-terms/terminator/terminator-1.92.ebuild b/x11-terms/terminator/terminator-1.92.ebuild
new file mode 100644
index 0000000..a0deaff
--- /dev/null
+++ b/x11-terms/terminator/terminator-1.92.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Multiple GNOME terminals in one window (patched by sgs)"
+HOMEPAGE="https://github.com/gnome-terminator/terminator"
+SRC_URI="https://github.com/gnome-terminator/terminator/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~x86"
+IUSE="dbus +libnotify test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	dev-libs/keybinder:3[introspection]
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=x11-libs/gtk+-3.16:3
+	x11-libs/vte:2.91[introspection]
+	dbus? ( sys-apps/dbus )
+	libnotify? ( x11-libs/libnotify[introspection] )
+"
+BDEPEND="
+	dev-util/intltool
+	test? ( ${RDEPEND} )
+"
+
+PATCHES=(
+	"${FILESDIR}"/terminator-1.91-without-icon-cache.patch
+	"${FILESDIR}"/terminator-1.91-desktop.patch
+        "${FILESDIR}"/${P}-single-tab.patch
+)
+
+src_prepare() {
+	xdg_environment_reset
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	virtx esetup.py test || die "tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
-- 
cgit v1.3