From 406221dc8d42a6beda5aca96dd7d668751e53635 Mon Sep 17 00:00:00 2001
From: Simeon Simeonov
Date: Wed, 8 Apr 2020 21:19:40 +0200
Subject: Initial release based on sgs' private overlay

---
 x11-terms/sakura/sakura-3.7.0.ebuild | 63 ++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 x11-terms/sakura/sakura-3.7.0.ebuild

(limited to 'x11-terms/sakura/sakura-3.7.0.ebuild')

diff --git a/x11-terms/sakura/sakura-3.7.0.ebuild b/x11-terms/sakura/sakura-3.7.0.ebuild
new file mode 100644
index 0000000..e53be0d
--- /dev/null
+++ b/x11-terms/sakura/sakura-3.7.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cmake-utils eutils flag-o-matic xdg-utils
+
+DESCRIPTION="sakura is a terminal emulator based on GTK and VTE"
+HOMEPAGE="http://www.pleyades.net/david/projects/sakura/"
+SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~x86 ~x86-linux"
+
+RDEPEND="
+	>=dev-libs/glib-2.20:2
+	>=x11-libs/gtk+-3.20:3[X]
+	x11-libs/libX11
+	>=x11-libs/vte-0.50:2.91
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-lang/perl-5.10.1
+	virtual/pkgconfig
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.7.0-gentoo.patch
+    "${FILESDIR}"/${PN}-3.7.0-single-tab.patch
+)
+DOCS=(
+	AUTHORS
+)
+
+src_prepare() {
+	strip-linguas -i po/
+	local lingua
+	for lingua in po/*.po; do
+		lingua="${lingua/po\/}"
+		lingua="${lingua/.po}"
+		if ! has ${lingua} ${LINGUAS}; then
+			rm po/${lingua}.po || die
+		fi
+	done
+
+	cmake-utils_src_prepare
+	# sakura.c:1740:3: warning: implicit declaration of function ‘readlink’
+	# [-Wimplicit-function-declaration]
+	append-cppflags -D_DEFAULT_SOURCE
+
+	# sakura.c:1348:9: error: ‘for’ loop initial declarations are only allowed
+	# in C99 or C11 mode
+	append-cflags -std=c99
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
-- 
cgit v1.3