From 406221dc8d42a6beda5aca96dd7d668751e53635 Mon Sep 17 00:00:00 2001
From: Simeon Simeonov
Date: Wed, 8 Apr 2020 21:19:40 +0200
Subject: Initial release based on sgs' private overlay

---
 mail-client/sylpheed/sylpheed-3.7.0-r1.ebuild | 76 +++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 mail-client/sylpheed/sylpheed-3.7.0-r1.ebuild

(limited to 'mail-client/sylpheed/sylpheed-3.7.0-r1.ebuild')

diff --git a/mail-client/sylpheed/sylpheed-3.7.0-r1.ebuild b/mail-client/sylpheed/sylpheed-3.7.0-r1.ebuild
new file mode 100644
index 0000000..f94d992
--- /dev/null
+++ b/mail-client/sylpheed/sylpheed-3.7.0-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 2018 Simeon Simeonov
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit eutils
+
+DESCRIPTION="A lightweight email client and newsreader (patched by sgs)"
+HOMEPAGE="http://sylpheed.sraoss.jp/"
+SRC_URI="http://${PN}.sraoss.jp/${PN}/v${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="crypt ipv6 ldap libressl nls oniguruma pda spell ssl xface"
+
+CDEPEND="net-libs/liblockfile
+	x11-libs/gtk+:2
+	crypt? ( app-crypt/gpgme )
+	ldap? ( net-nds/openldap )
+	nls? ( sys-devel/gettext )
+	oniguruma? ( dev-libs/oniguruma:= )
+	pda? ( app-pda/jpilot )
+	spell? (
+		app-text/gtkspell:2
+		dev-libs/dbus-glib
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)"
+RDEPEND="${CDEPEND}
+	app-misc/mime-types
+	net-misc/curl"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	xface? ( media-libs/compface )"
+
+PATCHES=(
+    "${FILESDIR}/${P}-signature-box.patch"
+    "${FILESDIR}/${P}-PGP-signature-fix.patch"
+    "${FILESDIR}/${P}-master-password.patch"
+    "${FILESDIR}/${P}-version.patch"
+)
+
+DOCS="AUTHORS ChangeLog* NEW* PLUGIN* README* TODO*"
+
+src_configure() {
+	local htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
+	econf \
+		$(use_enable crypt gpgme) \
+		$(use_enable ipv6) \
+		$(use_enable ldap) \
+		$(use_enable oniguruma) \
+		$(use_enable pda jpilot) \
+		$(use_enable spell gtkspell) \
+		$(use_enable ssl) \
+		$(use_enable xface compface) \
+		--with-plugindir="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins \
+		--with-manualdir="${htmldir}"/manual \
+		--with-faqdir="${htmldir}"/faq \
+        --disable-updatecheckplugin \
+		--disable-updatecheck
+}
+
+src_install() {
+	default
+
+	doicon *.png
+	domenu *.desktop
+
+	cd plugin/attachment_tool
+	emake DESTDIR="${D}" install-plugin
+	docinto plugin/attachment_tool
+	dodoc README
+}
-- 
cgit v1.3