blob: 4553e891d84a738f1b57d64cd4806945caad667f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Simeon Simeonov <sgs( AT )pichoveDOTorg>
pkgname=i3lock-extended
pkgver=3.2.15
pkgrel=1
pkgdesc='i3lock-extended - i3lock fork with additional functionality'
url='https://github.com/blackm0re/i3lock-extended'
arch=('x86_64')
license=('GPL-3+' 'BSD')
depends=(
'cairo' 'libcairo.so'
'glibc'
'libev' 'libev.so'
'libxcb'
'libxkbcommon' 'libxkbcommon.so'
'libxkbcommon-x11' 'libxkbcommon-x11.so'
'pam' 'libpam.so'
'xcb-util'
'xcb-util-image'
'xcb-util-xrm'
)
makedepends=(
'meson'
)
options=('docs')
backup=('etc/pam.d/i3lock-extended')
source=(https://github.com/blackm0re/i3lock-extended/releases/download/${pkgver}/$pkgname-$pkgver.tar.xz{,.asc})
b2sums=('001917e98564cdae8834142acfbf6e5424c041f6a96eb8e55017d414eda6d6f70068305bef2213295da6577dd8f16a6a9ff322705f9f0c563d7471097c906c83' 'cbcc71c7c22cfe0d5af3db3e490d7d0d550409b3588cc4e5f526923ea542cffc1c4b85ffe4c89eb236d3f2651dd5c51a0e4c94f72b2848210880be4e003a776c')
sha512sums=('b1b4c15fb7c03fb3dce036d9bb7f41e4702a0de4f4f4820a7d1dbe36f3b62007469f4c6b9b942788da5e905adf94ea4c831844924d019f20b5b126eb3b82af2f' '651b29cbe355c132eeb20d58a2d8f915f56c3cdb9336304475a1136807b96f31acf56b208f386515eb93f6eda944ef4c69efb82f39a20604627e7cc988ee3f12')
validpgpkeys=('A6645797661E2F473DD3FF06BCE70555C3BB08F7') # Simeon Simeonov
prepare() {
cd ${pkgname}-${pkgver}
# Fix ticket FS#31544, sed line taken from gentoo
sed -i -e 's:login:system-auth:' pam/i3lock-extended
}
build() {
arch-meson $pkgname-$pkgver build
meson compile -C build
}
package() {
DESTDIR="$pkgdir" meson install -C build
cd ${pkgname}-${pkgver}
install -Dm 644 i3lock-extended.1 -t "${pkgdir}/usr/share/man/man1"
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|
